Pseint: Uso de las Matrices o Arreglos Bidimensionales

Una vez visto el tema de vectores en Pseint, es hora de pasar al siguiente nivel que son los arreglos bidimensionales o las llamadas matrices. En esta ocasión aprenderás a operar   con este tipo de arreglos, a imprimir en pantalla, al manejo de índices tanto de columnas y filas, y  a su vez a comprender de manera gráfica como se constituye una matriz.

Es importante resaltar que debes tener claro el concepto de lo que es un vector unidimensional; ya que estos pre saberes te facilitaran entender lo que es un arreglo bidimensional y las situaciones problema, en las que se debe aplicar dicho concepto.

¿Qué es un arreglo bidimensional o matriz?

Cuando hablamos de matrices en el mundo de la programación te puedes imaginas tabla con filas y columnas que contiene los mismos tipos de datos. En sí es como tener una reunión de vectores o arreglos, uno debajo del otro.

Para que te hagas una ideas de lo que es un arreglo bidimensional no solo en programación, sino también en Pseint, te presentamos el siguiente gráfico:

matrices Pseint Indices Programacion

Como puedes observar una matriz está compuesta de columnas y filas, y sus posiciones se establecen siempre mencionando primero la fila y segundo la columna. Esto se puede evidenciar en la posición m[2][1] del gráfico, la cual indica que el objeto está en la fila 2 y la columna 1.

Por otra parte, se puede observar que la matriz contiene elementos de tipo carácter. En donde, tal como se había dicho, siempre toda la matriz trabajara un solo tipo de dato declarado.

¿Cómo se declara una matriz en PSeint?

Para declarar una matriz siempre es importante realizar tres cosas en Pseint antes de iniciar a operar con este tipo arreglo:

1) Definir el tipo de dato que va a manejar la matriz

2) Definir las dimensiones de la matriz, siempre iniciando con las filas y luego con las columnas.

3) Definir como enteros los índices de la matriz, tanto para el manejo de columnas y filas.

Dicho esto, en Pseint el pseudocódigo nos quedaría como:

Definir i,j como Entero
Definir M Como Caracter
Dimension  M[2,2];

¿Cómo imprimir  e ingresar datos una matriz usando PSeint?

Para la impresión de una matriz y el ingreso de datos es necesario usar los índices definidos anteriormente, junto a la estructura de control (Para). En el caso de no tener claro el uso del (Para) , te recomendamos leer: Estructuras de Control en Pseint: Condicionales-Repetitivos.

Ahora bien, el pseudocódigo  completo que nos permite la impresión de una matriz de 2×2, junto al ingreso de datos de tipo carácter con valor “a” es el siguiente:

Algoritmo matrices
Definir i,j como Entero
Definir M Como Caracter
Dimension M[2,2];
Para i<-1 Hasta 2 Con Paso 1 Hacer
    Para j<-1 Hasta 2 Con Paso 1 Hacer
       M[i,j]<-"a";
    Fin Para
Fin Para
Para i<-1 Hasta 2 Con Paso 1 Hacer
    Para j<-1 Hasta 2 Con Paso 1 Hacer
       Escribir Sin Saltar " " M[i,j];
    Fin Para
Escribir " "
Fin Para
FinAlgoritmo

El pseudocódigo que se ha resaltado en amarillo es el encargado de imprimir la matriz y el azul cielo es el encargado de recorrer la matriz e ingresar el valor “a” a cada uno de sus posiciones. Los puntos claves que se pueden observar en el pseudocódigo son los siguientes:

  • Las filas y columnas de una matriz en Pseint siempre inicializará en 1. Si lo haces en cero marcara un error.
  • Para recorrer una matriz de manera efectiva, primero debemos ingresar un (para) que recorra las filas y luego dentro de este, ingresamos otro (para) que se encargara de recorrer las columnas.
  • Al momento de insertar un dato este debe ser del mismo tipo que se ha definido inicialmente en la matriz, en el caso anterior tenemos una matriz definida con datos de tipo carácter. A su vez, deberá especificarse la posición como M[fila][columna], en donde insertaremos el dato.

Ejemplo de arreglos bidimensionales en Pseint

Realizar un programa que permita almacenar números reales en una matriz de orden 4×3, 4 filas y tres columnas. Y que al final se imprima la suma de cada uno de los números ingresados en la misma.

Algoritmo matrices
  Definir i,j como Entero
  Definir M,n,suma Como Real
  Dimension M[4,3];
  Para i<-1 Hasta 4 Con Paso 1 Hacer
      Para j<-1 Hasta 3 Con Paso 1 Hacer
        Escribir Sin Saltar"Ingresa el dato de la posición [", i,",",j,"]";
        Leer n;
        M[i,j]<-n;
        suma<-suma+M[i,j];
     Fin Para
   Fin Para
   Escribir "El resultado de la suma de todos los elementos de la matriz es :",suma;
FinAlgoritmo

Video Resumen del uso de Arreglos en PSeint

A continuación encontrarás un video resumen acerca de los diferentes tipos de arreglos, esto con el fin de consolidar los pre saberes aprendidos en este artículo.


Concluimos esta sección en la que se ha tratado los arreglos bidimensionales en Pseint, recuerden siempre inicializar los contadores en 1 para recorrer matrices y a su vez trabajar con el mismo tipo de dato en la matriz. Por ejemplo, en el caso anterior la matriz era de datos reales, por tanto la variable suma fue declarada como real, junto a la variable n que lee un número que ingresa el usuario y fue insertado en la matriz.

Déjanos tus comentarios:
Artículos Relacionados: