Estructuras de Control en Pseint: Condicionales-Repetitivos

Hoy aprenderás a operar las estructuras de control en PSeint mediante la implementación de algoritmos. Este tipo de estructuras nos permiten ejecutar  y determinar la cantidad de  veces que se deben ejecutar una serie de instrucciones.

Las estructuras de control las podemos diferenciar en dos partes de acuerdo a la forma en que operan:

  • Condicionales: Si-Entonces y selección múltiple.
  • Repetitivas: Mientras, Repetir y Para.

Estructuras Condicionales en Pseint con Ejemplos

Este tipo de estructuras obedecen a condiciones lógicas que atienden a una serie de instrucciones en caso de que la condición evaluada sea positiva. Es importante mencionar que este tipo de estructuras se ejecutan una sola vez, por tanto no son iterativas.

Pseint estructuras de datos

Uso del Si-Entonces o (If-Then)

Esta instrucción evalúa en una primera instancia una expresión lógica en el condicional, el cual puede retornar falso o verdadero. Si esta retorna verdadero se ejecutan las instrucciones del entonces, en el caso de retornar falso se ejecutaran las instrucciones del Sino. Su sintaxis en Pseint es la siguiente:

Si expresion_logica Entonces
   acciones_por_verdadero
SiNo
   acciones_por_falso
Fin Si

Por otra parte, es importante mencionar que este tipo de instrucción puede no tener la clausula Sino, quedando solamente como un Si-Entonces y no como un Si-Entonces-Sino. Un ejemplo del uso de esta instrucción sería el determinar si un número ingresado por un usuario es par o impar:

Algoritmo ejemplo1
Definir i Como Entero
Escribir "Dame un número: "
Leer i
Si (i%2=0) Entonces
  Escribir "Ingresaste un número par"
SiNo
  Escribir "Ingresaste un número impar"
Fin Si
FinAlgoritmo

Tal vez te pueda interesar: Extraer pares e impares en un Vector Aleatorio usando Pseint

Uso de la selección múltiple o (Select-If)

Este tipo de instrucción se diferencia de la anterior en la medida que ya no obedece a una expresión lógica en la que podamos usar los símbolos (==, > o <) como tal, sino a un valor numérico.

La estructura de este tipo de instrucción contiene una clausula que es De Otro Modo y esta se cumple en caso tal que ninguna de las anteriores opciones numéricas se cumplan. La sintaxis en Pseint de esta instrucción es la siguiente:

Segun variable_numerica Hacer
opcion_1:
secuencia_de_acciones_1
opcion_2:
secuencia_de_acciones_2
opcion_3:
secuencia_de_acciones_3
De Otro Modo:
secuencia_de_acciones_dom
Fin Segun

Un ejemplo de este tipo de instrucción se puede ejecutar en la realización de un menú inicial en el que el usuario digite la opción a realizar como un  dato número entero positivo.

Algoritmo ejemplo2
Definir n Como Entero
Escribir "1) Saludar"
Escribir "2) Despedir"
Escribir "3) Salir"
Escribir "Ingresa una opción de (1-3):"
leer n
Segun n Hacer
1:
Escribir "Escogiste Saludar"
2:
Escribir "Escogiste Despedir"
3:
Escribir "Escogiste Salir"
De Otro Modo:
Escribir "No escogiste ninguna opción de (1-3)."
Fin Segun
Escribir "Oprima una tecla para salir..."
FinAlgoritmo

Estructuras Repetitivas en PSeint

Estas estructuras permiten ejecutar una serie de instrucciones de manera iterativa, con la particularidad de cada una de ellas ejecuta la iteración con un contexto totalmente diferente. A continuación, aprenderás como aplicar estas estructuras y lo mejor de todo con algoritmos completos que podrás copiar en tu software PSeint para ejecutar.

Uso del Mientras Hacer o (While)

Esta instrucción evalúa inicialmente una expresión lógica, de esta ser verdadera ejecutará una serie de instrucciones dentro de ella, y esto lo hará hasta que vuelva a evaluar dicha expresión y esta retorne negativo. Su estructura en Pseint es la siguiente:

Mientras expresion_logica Hacer
secuencia_de_acciones
Fin Mientras

Un ejemplo de la aplicación de este tipo de instrucción se evidencia al crear un algoritmo que nos muestre los primeros números pares entre el intervalo de [2,40]:

Algoritmo ejemplo3
Definir n Como Entero
n=2
Mientras (n<=40) Hacer
Escribir Sin Saltar " ",n
n=n+2
FinMientras
FinAlgoritmo

Uso del Repetir Hasta Que o (do-while)

El Repetir-Hasta Que se usa cuando se necesite ejecutar la instrucción por primera vez sin la necesidad de evaluar ninguna expresión lógica. Este tipo de instrucción se usa mucho para la creación de menús de usuarios, o algún tipo de algoritmo en donde se le pide al usurario ingresar algún tipo de dato para ser evaluado.

La estructura en Pseint del (do-while) es la siguiente:

Repetir
secuencia_de_acciones
Hasta Que expresion_logica

El siguiente ejemplo de la estructura vista nos pide ingresar un número menor que 50, en caso tal que el número ingresado sea mayor que 50 o igual (esto se debe a que la condición es n<50),  volverá a preguntar por el ingreso de dicho número.

Algoritmo ejemplo4
Definir n Como Entero
Repetir
Escribir Sin Saltar "Ingresa un número menor que 50: "
Leer n
Hasta Que (n<50)
FinAlgoritmo

Uso del Para o (for)

El uso del Para se establece al momento de necesitar una iteración que se repita un numero determinado de veces, ya que este nos ofrece un valor inicial, un valor final y por ultimo un valor entre cada avance. La estructura dada en PSeint para este tipo de estructura es:

Para variable_numerica<-valor_inicial Hasta valor_final Con Paso paso Hacer
secuencia_de_acciones
Fin Para

El siguiente ejemplo nos muestra el uso del Para para la iteración de un proceso de impresión. En este caso se iniciará en 1 y se terminara en 8, con un paso de 1. Es importante siempre declarar la variable a usar en el Para al inicio del algoritmo, en este caso será i.

Algoritmo ejemplo6
Definir i Como Entero
Para i<-1 Hasta 8 Con Paso 1 Hacer
Escribir "Iteración " ,i
Fin Para
FinAlgoritmo
+ Artículos de Interés